/* proparse/api/loaddb1.p

Loads the schema for each database
Assumes that the alias DICTDB already exists

*/

DEFINE VARIABLE dictdb_orig AS CHARACTER NO-UNDO.
DEFINE VARIABLE dbnum       AS INTEGER NO-UNDO.
DEFINE VARIABLE i1          AS INTEGER NO-UNDO.


ASSIGN dictdb_orig = LDBNAME("dictdb").
REPEAT dbnum = 1 TO NUM-DBS:
  IF DBTYPE(dbnum) <> "PROGRESS" THEN NEXT.
  DELETE ALIAS DICTDB.
  CREATE ALIAS DICTDB FOR DATABASE VALUE(LDBNAME(dbnum)).
  RUN proparse/api/loaddb2.p.
END.
DELETE ALIAS dictdb.
CREATE ALIAS dictdb FOR DATABASE VALUE(dictdb_orig).
/* Now add the meta-schema into "dictdb" */
RUN schemaAddDb ("dictdb", OUTPUT i1).
FOR EACH DICTDB._file WHERE _file._tbl-type <> "T":U NO-LOCK BY _file._file-name:
  RUN schemaAddTable (LOWER(DICTDB._file._file-name), OUTPUT i1).
END.


PROCEDURE schemaAddDb EXTERNAL "proparse.dll" CDECL:
  DEFINE INPUT PARAMETER name AS CHARACTER.
  DEFINE RETURN PARAMETER theReturn AS LONG.
END.
PROCEDURE schemaAddTable EXTERNAL "proparse.dll" CDECL:
  DEFINE INPUT PARAMETER name AS CHARACTER.
  DEFINE RETURN PARAMETER theReturn AS LONG.
END.